Дневник Марины Новиковой http://www.liveinternet.ru/users/novprospekt/profile/

БлагоДарю

А потом делайте всё что надо: исправляйте, добавляйте. Людмила если есть скап. то я могу вам показать и рассказать как и что делать.

Боже мой....я еще и терминов тут не знаю, это как я понимаю, в исходнике надо взять код и его заполнить?
//Количество элементов карусели
const NUMBER_OF_ITEMS:uint = 20;

//Этот массив содержит все элементы карусели
var menuItems:Array = new Array();

//Устанавливаем фокальную длину
var focalLength:Number = 350;

//Устанавливаем точку вращения
var vanishingPointX:Number = stage.stageWidth / 2;
var vanishingPointY:Number = stage.stageHeight / 2;

//Высчитываем angleSpeed в слушателе ENTER_FRAME
var angleSpeed:Number = 0;

//Радиус окружности
var radius:Number = 128;

//Высчитываем разницу угла между элементами карусели (в радианах)
var angleDifference:Number = Math.PI * (360 / NUMBER_OF_ITEMS) / 180;

//Этот цикл создает и позиционирует элементы карусели
for (var i:uint = 0; i < NUMBER_OF_ITEMS; i++) {

//Создаем новый элемент
var menuItem:MenuItem = new MenuItem();

//Высчитываем стартовый угол
var startingAngle:Number = angleDifference * i;

//Устанавливаем "currentAngle" для элемента
menuItem.currentAngle = startingAngle;

//Позиционируем
menuItem.xpos3D = - radius * Math.cos(menuItem.currentAngle) * 0.5;
menuItem.ypos3D = radius * Math.sin(startingAngle);
menuItem.zpos3D = radius * Math.cos(startingAngle);

//Высчитываем размер для элемента (чем дальше , тем меньше)
var scaleRatio = focalLength/(focalLength + menuItem.zpos3D);

//Масштабируем элемент, в зависимости от полученных выше результатов
menuItem.scaleX = menuItem.scaleY = scaleRatio;

// Позиционируем элемент на сцене
menuItem.x = vanishingPointX + menuItem.xpos3D * scaleRatio;
menuItem.y = vanishingPointY + menuItem.ypos3D * scaleRatio;

//Добавляем прозрачности
menuItem.alpha = 0.3;

//Добавляем текст
menuItem.menuItemText.text = "flashmaster.org.ua " + i;

//Сделаем так, что бы текст не реагировал на события мыши
menuItem.mouseChildren = false;

//Добавим нужные слушатели событий к элементам карусели
menuItem.addEventListener(MouseEvent.MOUSE_OVER, mouseOverItem);
menuItem.addEventListener(MouseEvent.MOUSE_OUT, mouseOutItem);
menuItem.addEventListener(MouseEvent.CLICK, itemClicked);

//Добавим элемент в массив
menuItems.push(menuItem);

//Добавим элемент на сцену
addChild(menuItem);
}

//добавим слушатель события ENTER_FRAME для анимации
addEventListener(Event.ENTER_FRAME, moveCarousel);

//Эта функция вызывается в каждом кадре
function moveCarousel(e:Event):void {

//Высчитываем скорость поворота в зависимости от координаты мыши Y
angleSpeed = (mouseY - stage.stageHeight / 2) * 0.0002;

//Пробежимся циклом по всем элементам карусели
for (var i:uint = 0; i < NUMBER_OF_ITEMS; i++) {

//Добавим элемент в локальную переменную
var menuItem:MenuItem = (MenuItem)(menuItems[i]);

//Обновляем текущий угол элемента
menuItem.currentAngle += angleSpeed;

//Высчитываем размер
var scaleRatio = focalLength/(focalLength + menuItem.zpos3D);

//Масштабируем в зависимости от полученных выше результатов
menuItem.scaleX=menuItem.scaleY=scaleRatio;

//Устанавливаем новые 3D координаты
menuItem.xpos3D=- radius*Math.cos(menuItem.currentAngle)*0.5;
menuItem.ypos3D=radius*Math.sin(menuItem.currentAngle);
menuItem.zpos3D=radius*Math.cos(menuItem.currentAngle);

//Обновляем координаты элементов
menuItem.x=vanishingPointX+menuItem.xpos3D*scaleRatio;
menuItem.y=vanishingPointY+menuItem.ypos3D*scaleRatio;
}

//Вызываем функцию, которая правильно накладывает элементы друг на друга
sortZ();
}

//Опишем эту функцию
function sortZ():void {

//Ищем в массиве элемент, который имеет самую большую координату Z
menuItems.sortOn("zpos3D", Array.NUMERIC | Array.DESCENDING);

//Устанавливаем новый индекс
for (var i:uint = 0; i < NUMBER_OF_ITEMS; i++) {
setChildIndex(menuItems[i], i);
}
}

//Эта функция вызывается, когда мышь над элементом
function mouseOverItem(e:Event):void {

//Делаем объект не прозрачный
e.target.alpha=1;
}

//Эта функция вызывается, когда курсор мыши вне элемента
function mouseOutItem(e:Event):void {

//Добавляем прозрачность
e.target.alpha=0.3;
}

//Эта функция вызывается когда вы кликаете мышью по элементу
function itemClicked(e:Event):void {

trace("Вы только что кликнули на один из элементов");
}

Людмила, посмотрите на этой странице сам код и ниже там написано, где и что нужно менять http://www.liveinternet.ru/users/5093970/post325935849 Код не надо брать. Просто надо открыть "действие", нажав F9 и менять прямо там в своей работе. В исходниках никогда и ничего не надо менять, вы только можете посмотреть как и что там сделано, а менять можно в своей работе во фла.

я то карусель и делала по этому уроку, только не сохранила для себя...мне кажется, что мы не совсем понимаем друг друга....да я тут сидела, тыкала, заменила в том исходнике свое поставила, так семь пластин пустые стали....голова уже пухнет.... а тогда как я смогу с чужим исходником работать??? ничччего что то не догоняю... в ФШ то открыл, вот те слои и делай что хошь... Придется снова делать карусель, чтобы исходник для себя оставить....мне надо очень

Людмила, скайп есть? Если есть дайте ваш логин, я вам по скайпу всё расскажу и покажу.