CODE

package {
import flash.display.MovieClip;
import flash.display.Sprite;
import flash.events.Event;

/**
 * ...
 * @author MOHCTEP
 * @version:
 * @created: 14.03.2017 14:35
 * @description:
 * Flame - Класс пламени свечи
 */
public class Flame extends Sprite {
 /**
  * Конструктор класса. Дожидается добавления на сцену.
  */
 public function Flame() {
  stage ? init() : addEventListener(Event.ADDED_TO_STAGE, init);
 }
 
 /**** LISTENERS SECTION ****/
 
 /**
  * Сцена доступна - начинаем инсталляцию:
  * Подписываемся на событие перехода по кадрам - Event.ENTER_FRAME
  * и на событие завершения анимации будущих "частичек" пламени - Event.COMPLETE
  * @param e - Event.ADDED_TO_STAGE
  */
 private function init(e:Event = null):void {
  removeEventListener(Event.ADDED_TO_STAGE, init);
  addEventListener(Event.REMOVED_FROM_STAGE, destroyer);
  // entry point
  addEventListener(Event.ENTER_FRAME, flameBurn);
  addEventListener(Event.COMPLETE, removeBurn);
 }
 
 /**
  * "Ежекадровая" процедура.
  * "Добываем" из библиотеки 3 экземпляра "flame".
  * Ставим, масштабируем и поворачиваем их немножко рандомно.
  * И показываем, добавив в список отображения.
  * @param e - Event.ENTER_FRAME
  */
 private function flameBurn(e:Event):void {
  var new_flame:MovieClip;
  for (var i:int = 0; i < 3; i++) {
   new_flame = new flame();
   new_flame.x = Math.random()*2-1;
   new_flame.rotation = 1 + Math.random() * 3 - 3;
   new_flame.y = Math.random();
   new_flame.alpha = Math.random() * 0.5 + 0.5;
   new_flame.scaleX = .2 + Math.random() * .8;
   new_flame.scaleY = .5 + Math.random() * .7;
   addChild(new_flame);
  }
 }
 /**
  * Какой-то из ранее добавленных экземпляров пламени отчитался о завершении своей анимации.
  * Удалим его из списка отображения.
  * @param e - Event.COMPLETE
  */
 private function removeBurn(e:Event):void {
  removeChild(e.target as MovieClip);
 }
 /**
  * Нас удалили со сцены.
  * Отпишемся от всех, ранее назначенных, собвтий и почистим список отображения.
  * @param e - Event.REMOVED_FROM_STAGE
  */
 private function destroyer(e:Event):void {
  removeEventListener(Event.REMOVED_FROM_STAGE, destroyer);
  // remove all listeners, displayObjects, etc...
  removeEventListener(Event.ENTER_FRAME, flameBurn);
  removeEventListener(Event.COMPLETE, removeBurn);
  while (numChildren) removeChildAt(0);
 }
}

}

CODE

import flash.events.Event;

dispatchEvent(new Event(Event.COMPLETE,true));
stop();
//Остановим воспроизведение и рапортуем сцене о его завершении.

CODE

var fl:Flame = new Flame();
fl.x=274;
fl.y=216;
addChild(fl);